mirror of
git://sourceware.org/git/glibc.git
synced 2025-03-06 20:58:33 +01:00
2c1903cbba
The commit 'sparc: Use Linux kABI for syscall return' (86c5d2cf0c) did not take into account a subtle sparc syscall kABI constraint. For syscalls that might block indefinitely, on an interrupt (like SIGCONT) the kernel will set the instruction pointer to just before the syscall: arch/sparc/kernel/signal_64.c 476 static void do_signal(struct pt_regs *regs, unsigned long orig_i0) 477 { [...] 525 if (restart_syscall) { 526 switch (regs->u_regs[UREG_I0]) { 527 case ERESTARTNOHAND: 528 case ERESTARTSYS: 529 case ERESTARTNOINTR: 530 /* replay the system call when we are done */ 531 regs->u_regs[UREG_I0] = orig_i0; 532 regs->tpc -= 4; 533 regs->tnpc -= 4; 534 pt_regs_clear_syscall(regs); 535 fallthrough; 536 case ERESTART_RESTARTBLOCK: 537 regs->u_regs[UREG_G1] = __NR_restart_syscall; 538 regs->tpc -= 4; 539 regs->tnpc -= 4; 540 pt_regs_clear_syscall(regs); 541 } However, on a SIGCONT it seems that 'g1' register is being clobbered after the syscall returns. Before86c5d2cf0c, the 'g1' was always placed jus before the 'ta' instruction which then reloads the syscall number and restarts the syscall. On master, where 'g1' might be placed before 'ta': $ cat test.c #include <unistd.h> int main () { pause (); } $ gcc test.c -o test $ strace -f ./t [...] ppoll(NULL, 0, NULL, NULL, 0 On another terminal $ kill -STOP 2262828 $ strace -f ./t [...] --- SIGSTOP {si_signo=SIGSTOP, si_code=SI_USER, si_pid=2521813, si_uid=8289} --- --- stopped by SIGSTOP --- And then $ kill -CONT 2262828 Results in: --- SIGCONT {si_signo=SIGCONT, si_code=SI_USER, si_pid=2521813, si_uid=8289} --- restart_syscall(<... resuming interrupted ppoll ...>) = -1 EINTR (Interrupted system call) Where the expected behaviour would be: $ strace -f ./t [...] ppoll(NULL, 0, NULL, NULL, 0) = ? ERESTARTNOHAND (To be restarted if no handler) --- SIGSTOP {si_signo=SIGSTOP, si_code=SI_USER, si_pid=2521813, si_uid=8289} --- --- stopped by SIGSTOP --- --- SIGCONT {si_signo=SIGCONT, si_code=SI_USER, si_pid=2521813, si_uid=8289} --- ppoll(NULL, 0, NULL, NULL, 0 Just moving the 'g1' setting near the syscall asm is not suffice, the compiler might optimize it away (as I saw on cancellation.c by trying this fix). Instead, I have change the inline asm to put the 'g1' setup in ithe asm block. This would require to change the asm constraint for INTERNAL_SYSCALL_NCS, since the syscall number is not constant. Checked on sparc64-linux-gnu. Reported-by: René Rebe <rene@exactcode.de> Tested-by: Sam James <sam@gentoo.org> Reviewed-by: Sam James <sam@gentoo.org>
80 lines
1.8 KiB
ArmAsm
80 lines
1.8 KiB
ArmAsm
/* Cancellable syscall wrapper. Linux/sparc32 version.
|
|
Copyright (C) 2023 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include <descr-const.h>
|
|
|
|
/* long int __syscall_cancel_arch (int *cancelhandling,
|
|
long int nr,
|
|
long int arg1,
|
|
long int arg2,
|
|
long int arg3,
|
|
long int arg4,
|
|
long int arg5,
|
|
long int arg6) */
|
|
|
|
ENTRY (__syscall_cancel_arch)
|
|
save %sp, -96, %sp
|
|
|
|
cfi_window_save
|
|
cfi_register (%o7, %i7)
|
|
cfi_def_cfa_register (%fp)
|
|
|
|
.globl __syscall_cancel_arch_start
|
|
__syscall_cancel_arch_start:
|
|
|
|
/* if (*cancelhandling & CANCELED_BITMASK)
|
|
__syscall_do_cancel() */
|
|
ld [%i0], %g2
|
|
andcc %g2, TCB_CANCELED_BITMASK, %g0
|
|
#ifdef __sparcv9
|
|
bne,pn %icc, 2f
|
|
#else
|
|
bne 2f
|
|
#endif
|
|
/* Issue a 6 argument syscall. */
|
|
mov %i2, %o0
|
|
mov %i3, %o1
|
|
mov %i4, %o2
|
|
mov %i5, %o3
|
|
ld [%fp+92], %o4
|
|
ld [%fp+96], %o5
|
|
mov %i1, %g1
|
|
ta 0x10
|
|
|
|
.globl __syscall_cancel_arch_end
|
|
__syscall_cancel_arch_end:
|
|
bcc 1f
|
|
nop
|
|
sub %g0, %o0, %o0
|
|
1:
|
|
mov %o0, %i0
|
|
#ifdef __sparcv9
|
|
return %i7+8
|
|
nop
|
|
#else
|
|
jmp %i7+8
|
|
restore
|
|
#endif
|
|
|
|
2:
|
|
call __syscall_do_cancel, 0
|
|
nop
|
|
nop
|
|
|
|
END (__syscall_cancel_arch)
|